A/D変換の動作確認（２）
ソフト的な荒技を紹介（ＰＩＣをＳＬＥＥＰ！しながらA/D変換）
眠らせてA/D変換をするって？
Ａ/D モジュールはスリープ中も動作できます。
SLEEP 命令を実行させることで、ディジタル変換ノイズを除去することができます。変換が終了すると、GO/DONE ビットがクリアされて、結果がADRES
レジスタにロードされます。A/D モジュールがスリープ中に動作するには、A/D クロックソースをRC（ADCS1：ADCS0 = 11)に設定する必要があります。スリープ中に変換するには、GO/DONEビットをセットした後すぐにSLEEP
命令を実行します。
図１にA/D変換のフローチャートを示します。
プログラムの解説については、「プログラムの説明（２）」の項をご参照ください。
 |
| 図１．A/D変換プログラム（２） フローチャート |
（注）以下に示すプログラムには、ホームページ画面作成の都合上、空白として全角文字のスペースなどが挿入されています。したがって、下記プログラムリストをそのままコピーしてＭＰＬＡＢのソースファイルとされた場合には、エラーとなることがあります。
→ここをクリックして、下記のプログラムをダウンロードするようにしてください。
ファイル名：「adconv2.asm」 サイズ２．２７ｋバイト
→ここをクリックして、下記のオブジェクトファイルをダウンロードするようにしてください。
ファイル名：「adconv2.hex」 サイズ１１７３バイト
プログラムリスト中、青字となっている行が、前ページのA/D変換プログラム（１）で変更された部分です。
| ;*********************************************************** ; A/D変換動作チェックプログラム（２） ; スリープ機能使用（A/D 割り込み使用） ; A/D変換入力端子（CH0／RA0） ; A/D変換の結果はLED点灯により確認 ; RB1(MSB),RB0,RD7,RD6,RD5,RD4,RD3,RD2,RD1,RD0(LSB) ; の１０ビット ;*********************************************************** |
|
| LIST P=PIC16F877 INCLUDE P16F877.INC |
;（１）プロセッサの種別指定 ;（２）インクルードファイルの指定 |
| ;*********************************************************** ; 変数定義とレジスタ割付 ;*********************************************************** |
|
| COUNT EQU 20H ORG 0 |
;（３）ループカウンタ ;（４）プログラムの開始番地の指定 |
| ;*********************************************************** ; 入出力ピン初期化 ;*********************************************************** |
|
| BSF STATUS,RP0 MOVLW B'10001110' MOVWF ADCON1 BSF PIE1,ADIE CLRF TRISB CLRF TRISD BCF STATUS,RP0 MOVLW B'11000001' MOVWF ADCON0 BSF INTCON,PEIE |
;（５）Bank 1 へ切替 ;（６）RA0のみアナログ、結果右詰 ;（７）ADCON1レジスタの設定 ;（7'）A/D 割り込みを発生可にする ;（８）PortB 出力モードに設定 ; PortD 出力モードに設定 ;（９）Bank 0 へ戻す ; ;（10'）Frc,CH0 設定, A/D on ;（11）ADCON0レジスタの設定 ;（11'）周辺割り込みを発生させる |
| ;*********************************************************** ; メインプログラム ;*********************************************************** |
|
| ADSTART BCF PIR1,ADIF CALL TIME BSF ADCON0,GO SLEEP MOVF ADRESH,W MOVWF PORTB BSF STATUS,RP0 MOVF ADRESL,W BCF STATUS,RP0 MOVWF PORTD GOTO ADSTART |
; ;（12')A/D 割り込みフラグビットをクリアする ;（12）23.2μs 一定時間待つ ; （2TAD [2×1.6μｓ]＋アクィジション時間[20μｓ]） ;（13）A/D スタート ;（13'）SLEEP 命令を実行 ; ;（16）A/D データ上位（データは右詰） ;（17）PortBへ A/D 結果を出力 ;（18）Bank 1 へ切替 ;（19）A/D データ下位 ;（20）Bank 0 へ戻す ;（21）PortDへ A/D 結果を出力 ;（22）A/D 変換を繰り返す |
| ;*********************************************************** ;２３μｓ遅延サブルーチン（２０ＭＨｚクロック時） ;*********************************************************** |
|
| TIME MOVLW 25H MOVWF COUNT NOP LOOP DECFSZ COUNT,F GOTO LOOP RETURN END |
; ;（23）1サイクル 25H = 37 ;（24）1サイクル ;（25）1サイクル 微調整ダミー ; ;（26）1×(37-1)＋2 = 38サイクル ;（27）2×(37-1) = 72サイクル ;（28）2サイクル ; 合計 115サイクル×0.2μｓ = 23μｓ ;（29）プログラム・ソースの終わり |
【プログラムの説明（２）】
このプログラムについて、解説を加えておきましょう。ただし、前ページで解説したプログラム（１）の説明と重複する部分は省略します。
ここではプログラムリスト中、青字となっている行を解説します。その他の行はプログラムの説明（１）をご覧ください。
（７’）A/D 割り込みを発生可にする
ＰＩＥ１レジスタは周辺機能の割り込みのイネーブルビットが割り当てられています。
ＰＩＥ１レジスタの６ビット目のＡＤＩＥビットは、A/D変換器割り込みイネーブルビットとなっていて、
ＡＤＩＥ＝１ ：A/D変換割り込みを使用可能にする
ＡＤＩＥ＝０ ：A/D変換割り込みを発生不可にする
BSF PIE1,ADIE
「ＰＩＥ１」レジスタのＡＤＩＥビットを「１」にし、A/D変換割り込みを使用可能にする
（10’）Frc，CH0 設定，A/D on
SLEEPモードでA/D変換を行うため、A/D クロックソースをRC(ADCS1:ADCS0=11)にセットする必要があります。
「A/D変換の制御法」の表４．A/D変換用クロックの選択を参照してください。内部ＲＣ発振回路を使用するＦｒｃ指定の場合は、システムクロックには影響されず、２〜６μｓの周波数になります。また、「A/D変換の制御法」の表１．ＡＤＣＯＮ０レジスタの機能説明表を参照してください。アナログチャネル指定ビットですが、CHSx＝「000」とすることで、ＣＨ０（ＲＡ０）の指定になります。
bit7： A/D変換クロック（Frc）指定より ADCS1＝「１」
bit6： A/D変換クロック（Frc）指定より ADCS0＝「１」
bit5： アナログチャネルＣＨ０（ＲＡ０）指定より、CHS2＝「０」
bit4： アナログチャネルＣＨ０（ＲＡ０）指定より、CHS1＝「０」
bit3： アナログチャネルＣＨ０（ＲＡ０）指定より、CHS0＝「０」
bit2： A/D 変換ステータスビット（初期設定時は「０」としておく）
bit1： 機能なし（とりあえず「０」とでもしておく）
bit0： A/D ON ビット（A/D機能を使うので「１」としておく）
ということで、Ｂ’１１０００００１’ （Ｃ１Ｈ）をＷｒｅｇにロードする。
（11’）周辺割り込みを発生させる
INTCON レジスタは割り込みの各種イネーブルおよびフラグビットが割り当てられているレジスタです。周辺機能の割り込みを使用可能にするためには、INTCONレジスタのPEIE
ビットをセットします。
INTCONレジスタの６ビット目のＰＥＩＥビットは、周辺割り込みイネーブルビットとなっていて、
ＰＥＩＥ＝１：すべてのマスクされていない周辺機能の割り込みを使用可能にする
ＰＥＩＥ＝０：すべての周辺機能の割り込みを使用不可にする
BSF INTCON,PEIE
「INTCON」レジスタのＰＥＩＥビットを「１」にし、周辺機能の割り込みを使用可能にする
（12’）A/D 割り込みフラグビットをクリアする
PIR1レジスタは周辺機能の割り込みのフラグビットが割り当てられています。
PIR1レジスタの６ビット目のADIFビットは、AD
コンバータ割り込みフラグビットとなっていて、
ＡＤＩＦ＝１：A/D変換が完了した
ＡＤＩＦ＝０：A/D変換が完了していない
BCF PIR1,ADIF
A/D変換をこれから行うため、「PIR1」レジスタのADIFビットを「０」にする。
（1３’）SLEEP 命令を実行
ADCON０レジスタのGOビットをセットし、A/D変換を開始した直後に、プロセッサをＳＬＥＥＰモードにします。A/D
モジュールはスリープ中も動作できます。
ＳＬＥＥＰにする利点は、ディジタル変換ノイズを除去することです。
A/D変換が終了すると、PIR1レジスタの６ビット目のADIFビットが「１」にセットされ、結果がADRES
レジスタにロードされます。
表１にＳＬＥＥＰさせたときのA/D変換の実測結果と理論値を示します。ターゲットボードの値（実測値）と理論値を比べてみると、２Ｖ〜３Ｖあたりで最大２ＬＳＢの誤差があることが分かります。電圧換算すると、
２／１０２３×４．９７Ｖ＝約９．７ｍＶ程度になりました。
前ページ表２に示した通常のA/D変換動作の結果と大差ないことが確認されました。この結果から考えると、通常動作のA/D変換においてもディジタル変換ノイズの影響は小さく、わざわざＳＬＥＥＰさせてクロックを止めたりしなくても通常にA/D変換機能を使えばよいことが分かりました。ただし、ＧＮＤラインを貧弱な配線にしたりすると、場合によっては、ディジタル変換ノイズの影響を受けてしまうこともあり得ます。そのときは、ＳＬＥＥＰさせることでノイズの除去効果が期待できると思います。（しかし私の考えとしては、こんなソフト的な荒技を使うより、まず第一に配線パターンを改善した方がよろしいかと思いますが。。。(^^;）
| A/D変換 入力電圧 （ ）内は実測値 |
出力結果 | |||||
| ターゲットボード | 理論値 | |||||
| ２進 | １６進 | １０進 | ２進 | １６進 | １０進 | |
| ５Ｖ （４．９７Ｖ） |
Ｂ’１１１１１１１１１１’ | Ｈ’３ＦＦ’ | Ｄ’１０２３’ | Ｂ’１１１１１１１１１１’ | Ｈ’３ＦＦ’ | Ｄ’１０２３’ |
| ４Ｖ （４．００Ｖ） |
Ｂ’１１００１１１０００’ | Ｈ’３３８’ | Ｄ’８２４’ | Ｂ’１１００１１０１１１’ | Ｈ’３３７’ | Ｄ’８２３’ |
| ３Ｖ （３．００１Ｖ） |
Ｂ’１００１１０１０００’ | Ｈ’２６８’ | Ｄ’６１６’ | Ｂ’１００１１０１０１０’ | Ｈ’２６Ａ’ | Ｄ’６１８’ |
| ２Ｖ （２．００１Ｖ） |
Ｂ’０１１００１１０１０’ | Ｈ’１９Ａ’ | Ｄ’４１０’ | Ｂ’０１１００１１１００’ | Ｈ’１９Ｃ’ | Ｄ’４１２’ |
| １Ｖ （１．００１Ｖ） |
Ｂ’００１１００１１０１’ | Ｈ’０ＣＤ’ | Ｄ’２０５’ | Ｂ’００１１００１１１０’ | Ｈ’０ＣＥ’ | Ｄ’２０６’ |
| ０Ｖ （０．０００Ｖ） |
Ｂ’００００００００００’ | Ｈ’０００’ | Ｄ’０００’ | Ｂ’００００００００００’ | Ｈ’０００’ | Ｄ’０００’ |
次へは、「多入力のA/D変換法」について解説します。
 |
 |
 |
|